U<x>:=PolynomialRing(Rationals());
R:=RealField();
C<i>:=ComplexField();
pi:=Pi(R);

/////////////// Example session on Saturday 11.8.2012

///////////////////////////////// Dedekind zeta

K:=CyclotomicField(7);
L:=LSeries(K);
Evaluate(L,2);

K:=NumberField(x^4-2);
L:=LSeries(K)/RiemannZeta();

Evaluate(L,1);
h:=ClassNumber(K); 
h;
R:=Regulator(K);
D:=Discriminant(IntegerRing(K)); D;

2*h*R*(2*pi)/Sqrt(Abs(D));

/////////////////////////////// Elliptic curves

E:=EllipticCurve("37a1");
E;
Conductor(E);
Discriminant(E);
#TorsionSubgroup(E);
Rank(E);
Generators(E);
L:=LSeries(E);
Evaluate(L,1);
Evaluate(L,1: Derivative:=1);
Evaluate(L,1: Derivative:=1)/Regulator(E)/Periods(E)[1];

// Other basic L-functions: Modular forms, Dirichlet characters, 
// Hecke characters, hyperelliptic curves (+ Hilbert modular forms),

K:=NumberField(x^7-7*x-3);
G:=GaloisGroup(K);
#G;
GroupName(G);
IsSimple(G);
A:=ArtinRepresentations(K);A;
L:=LSeries(A[2]); L;
Conductor(L);
LCfRequired(L);

Evaluate(L,1);

// Number fields via Artin representations

L:=LSeries(SplittingField(x^8-2));
L;
Conductor(L);
Evaluate(L,2);
L`prod;

// Tensor products I

E:=EllipticCurve("11a1"); E;
LE:=LSeries(E);

M:=ModularForms(Gamma0(7),4);
Newforms(M);
f:=Newforms(M)[1][1];
Lf:=LSeries(f);

L:=TensorProduct(LE,Lf);

Evaluate(L,1);
CheckFunctionalEquation(L);

// Tensor products II

E:=EllipticCurve([0,0,0,-25,0]); E;
LE:=LSeries(E);
K:=NumberField(x^2-5);
LK:=LSeries(K);
L:=TensorProduct(LE,LK);
CheckFunctionalEquation(L);
EulerFactor(LE,2);
EulerFactor(L,2);
E:=EllipticCurve([GF(5)|0,0,0,-1,0]);
EulerFactor(E);
L:=TensorProduct(LE,LK,[<5,2,1+2*x+5*x^2>]);
CheckFunctionalEquation(L);
Evaluate(L,1+3*i);

 // Sign in the functional equation recognized as an algebraic number

K:=CyclotomicField(5);
A:=ArtinRepresentations(K);
L:=LSeries(A[2]);
Evaluate(L,1);          
sign:=Sign(L); sign;           
f:=PowerRelation(sign,8); 
f;  

// Self-made L-function of a Dirichlet character of conductor 3

L:=LSeries(1,[1],3,func<n|LegendreSymbol(n,3)>);  
CheckFunctionalEquation(L);